define L3OUTRO_INCER	= 2
define L3GLOBAL_TIME	= 20

//-----------------------------------------------------------
// Land 3 outro dialogue
//-----------------------------------------------------------
begin script Land3OutroDialogue
start

	begin known cinema		

		eject evil spirit
		say "BW2T_SCRIPT_03FINAL_PDM_ENDLAND_OUTRO_10"
		wait until read
		eject good spirit
		say "BW2T_SCRIPT_03FINAL_PDM_ENDLAND_OUTRO_20"
		wait until read
		say "BW2T_SCRIPT_03FINAL_PDM_ENDLAND_OUTRO_30"
		wait until read
		send good spirit home
		send evil spirit home

		L3_Leave = 1
	end known cinema

end script Land3OutroDialogue


begin script Land3Outro

	MovePos		= marker at {4747.776, 237.775, 1681.232}
	FoveFoc		= marker at {4844.651, 215.504, 1692.328}
	TimeLeft	= L3GLOBAL_TIME
	TeleportEffect	=	0
start

begin cinema

	set fade red 0 green 0 blue 0 time 2
	wait 2 seconds
	
	set camera lens 70.000
	TeleportEffect = create visual effect VISUAL_EFFECT_TELEPORTER_HOOP at {945.869, 377.945, 1639.584} time -1
	ALTITUDE of TeleportEffect = 2

	if SkipAllTutorials == 1
		reset camera path
		queue camera move with position {1160, 700, 2400} focus {1088, 442.420, 1616} time 0.0
		queue camera move with position {670, 700, 1800} focus {1088, 442.420, 1616} time 7.0
		queue camera move with position {620, 700, 1250} focus {1088, 442.420, 1616} time 6.0
		queue camera move with position {1147.842, 489.305, 1399.295} focus {1125.589, 442.420, 1484.769} time 4.0
		play camera path with easein 8 easeout 8 method SCRIPT_CAMERAPATH_SMOOTHEST
		set fade in time 2
		wait 1 seconds
		if MigrationOrConquest > 0
			start music "cut_scene_happy_02"
			eject good spirit
			//Good
			//Wonderful. You are a Good god! See what happened? People chose to join us! Let's all rejoice!
			say "BW2T_SCRIPT_03FINAL_ADVISORS_ARMY_TUT_210"
			wait until read
			//I knew you'd make the right choice.
			say "BW2T_SCRIPT_03FINAL_BUILDTABTUTORIAL_530"
			wait until read
			send good spirit home
		elsif MigrationOrConquest < 0
			start music "cut_scene_evil_34s_01"
			eject evil spirit
			//Evil
			//Yes! I knew you had it in you, Boss!
			say "BW2T_SCRIPT_03FINAL_PATERNITYSUIT_ADVISORS_20"
			wait until read
			//We don't want their prayers, we want them ready to fight!
			say "BW2T_SCRIPT_03FINAL_BUILDTABTUTORIAL_510"
			wait until read
			//Attacking. The best, and the most fun form of defense. I vote for battle. Get our retaliation in first!
			say "BW2T_SCRIPT_03FINAL_ADVISORS_ARMY_TUT_220"
			wait until read
			send evil spirit home
		else
			start music "farming_success_land2"
			eject good spirit
			eject evil spirit
			//Neutral
			//Now, what kind of god you're going to be is up to you.
			say "BW2T_SCRIPT_02FINAL_PDM_STARTLAND_50"
			wait until read
			//A god of peace and civilization.
			say "BW2T_SCRIPT_02FINAL_PDM_STARTLAND_60"
			wait until read
			//Or a god of war and destruction.
			say "BW2T_SCRIPT_02FINAL_PDM_STARTLAND_70"
			wait until read
			send good spirit home
			send evil spirit home
		end if
		wait until camera ready
		stop music with fadetime 2
		wait 2 seconds
	end if

	reset camera path 

	queue camera move with position {1147.842, 489.305, 1399.295} focus {1125.589, 442.420, 1484.769} time 0.0
	queue camera move with position {1408.638, 867.152, -499.628} focus {1403.938, 822.700, -410.174} time 40.0

	if SkipAllTutorials == 0
    	play camera path with easein 0 easeout 0.5 method SCRIPT_CAMERAPATH_EQUALDISTANCE

		set fade in time 2
		wait 1 seconds
	else
    	play camera path with easein 1 easeout 0.5 method SCRIPT_CAMERAPATH_EQUALDISTANCE
	end if
	start music "menumusic"

	eject good spirit
	eject evil spirit

	make good spirit play across 0.5 down 0.5 HELPDUDE_KM_03FINAL_ADVISORS_OUTRO_G_10_20
	make evil spirit play across 0.5 down 0.5 HELPDUDE_KM_03FINAL_ADVISORS_OUTRO_E_10_20
	wait until read
	send good spirit home
	send evil spirit home
	wait 3 seconds
	eject good spirit
	eject evil spirit
	make good spirit play across 0.5 down 0.5 HELPDUDE_KM_03FINAL_ADVISORS_OUTRO_G_30_40
	make evil spirit play across 0.5 down 0.5 HELPDUDE_KM_03FINAL_ADVISORS_OUTRO_E_30_40
	wait until read

	send good spirit home
	send evil spirit home

	//set camera lens 133.000 time 3

	set fade red 0 green 0 blue 0 time 1
	wait 1 seconds
	reset camera path 

	set camera position to {923.727, 396.406, 1658.786}
	set camera focus to {1011.654, 369.475, 1619.504}
	set fade in time 1


	wait 3.5 seconds
	//set fade red 255 green 255 blue 255 time 0.5
	reset camera path 


	//wait 2 seconds

	end cinema// with widescreen


end script Land3Outro